lib/std/lang/gen/bitset.ras 2.5 KiB raw
1
//! Word-wise bitset operations. Vector state is caller-saved.
2
// Shift from 32-bit word counts to byte counts.
3
.constant WORD_BYTE_SHIFT 2;
4
.text;
5
// a0 and a1 address count initialized words; a2 is the word count.
6
.export @"std::lang::gen::bitset::unionWords";
7
@"std::lang::gen::bitset::unionWords"
8
    beqz %a2 @unionWordsDone;
9
@unionWordsLoop
10
    vsetvli %t0 %a2 e32 m8 ta ma;
11
    vle32.v %v8 (%a0);
12
    vle32.v %v16 (%a1);
13
    vor.vv %v8 %v8 %v16;
14
    vse32.v %v8 (%a0);
15
    slli %t1 %t0 WORD_BYTE_SHIFT;
16
    add %a0 %a0 %t1;
17
    add %a1 %a1 %t1;
18
    sub %a2 %a2 %t0;
19
    bnez %a2 @unionWordsLoop;
20
@unionWordsDone
21
    ret;
22
23
// a0 and a1 address count initialized words; a2 is the word count.
24
.export @"std::lang::gen::bitset::subtractWords";
25
@"std::lang::gen::bitset::subtractWords"
26
    beqz %a2 @subtractWordsDone;
27
@subtractWordsLoop
28
    vsetvli %t0 %a2 e32 m8 ta ma;
29
    vle32.v %v8 (%a0);
30
    vle32.v %v16 (%a1);
31
    vandn.vv %v8 %v8 %v16;
32
    vse32.v %v8 (%a0);
33
    slli %t1 %t0 WORD_BYTE_SHIFT;
34
    add %a0 %a0 %t1;
35
    add %a1 %a1 %t1;
36
    sub %a2 %a2 %t0;
37
    bnez %a2 @subtractWordsLoop;
38
@subtractWordsDone
39
    ret;
40
41
// a0 and a1 address initialized words; a2 is the word count.
42
.export @"std::lang::gen::bitset::equalWords";
43
@"std::lang::gen::bitset::equalWords"
44
    beqz %a2 @equalDone;
45
@equalLoop
46
    vsetvli %t0 %a2 e32 m8 ta ma;
47
    vle32.v %v8 (%a0);
48
    vle32.v %v16 (%a1);
49
    vmsne.vv %v0 %v8 %v16;
50
    vcpop.m %t1 %v0;
51
    bnez %t1 @unequal;
52
    slli %t1 %t0 WORD_BYTE_SHIFT;
53
    add %a0 %a0 %t1;
54
    add %a1 %a1 %t1;
55
    sub %a2 %a2 %t0;
56
    bnez %a2 @equalLoop;
57
@equalDone
58
    li %a0 1;
59
    ret;
60
@unequal
61
    li %a0 0;
62
    ret;
63
64
// a0 is live-in; a1 is live-out; a2 is defs; a3 is uses; a4 is the word count.
65
.export @"std::lang::gen::bitset::liveWords";
66
@"std::lang::gen::bitset::liveWords"
67
    li %t2 0;
68
    beqz %a4 @liveDone;
69
@liveLoop
70
    vsetvli %t0 %a4 e32 m4 ta ma;
71
    vle32.v %v4 (%a0);
72
    vle32.v %v8 (%a1);
73
    vle32.v %v12 (%a2);
74
    vle32.v %v16 (%a3);
75
    vandn.vv %v8 %v8 %v12;
76
    vor.vv %v8 %v8 %v16;
77
    vmsne.vv %v0 %v4 %v8;
78
    vcpop.m %t1 %v0;
79
    or %t2 %t2 %t1;
80
    vse32.v %v8 (%a0);
81
    slli %t1 %t0 WORD_BYTE_SHIFT;
82
    add %a0 %a0 %t1;
83
    add %a1 %a1 %t1;
84
    add %a2 %a2 %t1;
85
    add %a3 %a3 %t1;
86
    sub %a4 %a4 %t0;
87
    bnez %a4 @liveLoop;
88
@liveDone
89
    snez %a0 %t2;
90
    ret;
91
92
// a0 addresses writable words; a1 is a nonzero word count.
93
.export @"std::lang::gen::bitset::clearWords";
94
@"std::lang::gen::bitset::clearWords"
95
    slli %a1 %a1 WORD_BYTE_SHIFT;
96
    li %a2 0;
97
    j @"std::mem::fillBytes";