//! Word-wise bitset operations. Vector state is caller-saved.
// Shift from 32-bit word counts to byte counts.
.constant WORD_BYTE_SHIFT 2;
.text;
// a0 and a1 address count initialized words; a2 is the word count.
.export @"std::lang::gen::bitset::unionWords";
@"std::lang::gen::bitset::unionWords"
    beqz %a2 @unionWordsDone;
@unionWordsLoop
    vsetvli %t0 %a2 e32 m8 ta ma;
    vle32.v %v8 (%a0);
    vle32.v %v16 (%a1);
    vor.vv %v8 %v8 %v16;
    vse32.v %v8 (%a0);
    slli %t1 %t0 WORD_BYTE_SHIFT;
    add %a0 %a0 %t1;
    add %a1 %a1 %t1;
    sub %a2 %a2 %t0;
    bnez %a2 @unionWordsLoop;
@unionWordsDone
    ret;

// a0 and a1 address count initialized words; a2 is the word count.
.export @"std::lang::gen::bitset::subtractWords";
@"std::lang::gen::bitset::subtractWords"
    beqz %a2 @subtractWordsDone;
@subtractWordsLoop
    vsetvli %t0 %a2 e32 m8 ta ma;
    vle32.v %v8 (%a0);
    vle32.v %v16 (%a1);
    vandn.vv %v8 %v8 %v16;
    vse32.v %v8 (%a0);
    slli %t1 %t0 WORD_BYTE_SHIFT;
    add %a0 %a0 %t1;
    add %a1 %a1 %t1;
    sub %a2 %a2 %t0;
    bnez %a2 @subtractWordsLoop;
@subtractWordsDone
    ret;

// a0 and a1 address initialized words; a2 is the word count.
.export @"std::lang::gen::bitset::equalWords";
@"std::lang::gen::bitset::equalWords"
    beqz %a2 @equalDone;
@equalLoop
    vsetvli %t0 %a2 e32 m8 ta ma;
    vle32.v %v8 (%a0);
    vle32.v %v16 (%a1);
    vmsne.vv %v0 %v8 %v16;
    vcpop.m %t1 %v0;
    bnez %t1 @unequal;
    slli %t1 %t0 WORD_BYTE_SHIFT;
    add %a0 %a0 %t1;
    add %a1 %a1 %t1;
    sub %a2 %a2 %t0;
    bnez %a2 @equalLoop;
@equalDone
    li %a0 1;
    ret;
@unequal
    li %a0 0;
    ret;

// a0 is live-in; a1 is live-out; a2 is defs; a3 is uses; a4 is the word count.
.export @"std::lang::gen::bitset::liveWords";
@"std::lang::gen::bitset::liveWords"
    li %t2 0;
    beqz %a4 @liveDone;
@liveLoop
    vsetvli %t0 %a4 e32 m4 ta ma;
    vle32.v %v4 (%a0);
    vle32.v %v8 (%a1);
    vle32.v %v12 (%a2);
    vle32.v %v16 (%a3);
    vandn.vv %v8 %v8 %v12;
    vor.vv %v8 %v8 %v16;
    vmsne.vv %v0 %v4 %v8;
    vcpop.m %t1 %v0;
    or %t2 %t2 %t1;
    vse32.v %v8 (%a0);
    slli %t1 %t0 WORD_BYTE_SHIFT;
    add %a0 %a0 %t1;
    add %a1 %a1 %t1;
    add %a2 %a2 %t1;
    add %a3 %a3 %t1;
    sub %a4 %a4 %t0;
    bnez %a4 @liveLoop;
@liveDone
    snez %a0 %t2;
    ret;

// a0 addresses writable words; a1 is a nonzero word count.
.export @"std::lang::gen::bitset::clearWords";
@"std::lang::gen::bitset::clearWords"
    slli %a1 %a1 WORD_BYTE_SHIFT;
    li %a2 0;
    j @"std::mem::fillBytes";
