lib/std/hash/blake3.ras 3.0 KiB raw
1
//! Four-lane BLAKE3 compression with Zve64x and Zvbb.
2
// Vector registers, vl and vtype are caller-saved. VLEN must be at least 64.
3
// BLAKE3 compression block size and number of rounds.
4
.constant BLOCK_BYTES 64;
5
.constant ROUNDS 7;
6
// Right rotations in one BLAKE3 mixing operation.
7
.constant ROTATE_FIRST 16;
8
.constant ROTATE_SECOND 12;
9
.constant ROTATE_THIRD 8;
10
.constant ROTATE_FOURTH 7;
11
.text;
12
// a0 addresses 64 writable bytes; a1 addresses 64 readable bytes.
13
.export @"std::hash::blake3::loadBlock";
14
@"std::hash::blake3::loadBlock"
15
    li %t0 BLOCK_BYTES;
16
    vsetvli %zero %t0 e8 m8 ta ma;
17
    vle8.v %v8 (%a1);
18
    vse8.v %v8 (%a0);
19
    ret;
20
21
// a0 addresses eight output words; a1 addresses eight chaining words.
22
// a2 addresses 16 message words; a3 addresses four metadata words.
23
// a4 addresses four IV words; a5 addresses 112 message offsets.
24
// m2 provides four 32-bit lanes when VLEN is at least 64 bits.
25
.export @"std::hash::blake3::compressWords";
26
@"std::hash::blake3::compressWords"
27
    vsetivli %zero 4 e32 m2 ta ma;
28
    vle32.v %v8 (%a1);
29
    addi %t0 %a1 16;
30
    vle32.v %v10 (%t0);
31
    vle32.v %v12 (%a4);
32
    vle32.v %v14 (%a3);
33
    mv %a1 %a2;
34
    mv %a2 %a5;
35
    // Lane indices for left rotations by one, two and three words.
36
    vid.v %v2;
37
    vadd.vi %v4 %v2 2;
38
    vand.vi %v4 %v4 3;
39
    vadd.vi %v6 %v2 3;
40
    vand.vi %v6 %v6 3;
41
    vadd.vi %v2 %v2 1;
42
    vand.vi %v2 %v2 3;
43
    li %t1 ROUNDS;
44
@round
45
    // Mix columns, then align the rows for the diagonal phase.
46
    vle32.v %v24 (%a2);
47
    addi %a2 %a2 16;
48
    vluxei32.v %v26 (%a1) %v24;
49
    vadd.vv %v8 %v8 %v10;
50
    vadd.vv %v8 %v8 %v26;
51
    vxor.vv %v14 %v14 %v8;
52
    vror.vi %v14 %v14 ROTATE_FIRST;
53
    vadd.vv %v12 %v12 %v14;
54
    vxor.vv %v10 %v10 %v12;
55
    vror.vi %v10 %v10 ROTATE_SECOND;
56
    vle32.v %v24 (%a2);
57
    addi %a2 %a2 16;
58
    vluxei32.v %v26 (%a1) %v24;
59
    vadd.vv %v8 %v8 %v10;
60
    vadd.vv %v8 %v8 %v26;
61
    vxor.vv %v14 %v14 %v8;
62
    vror.vi %v14 %v14 ROTATE_THIRD;
63
    vadd.vv %v12 %v12 %v14;
64
    vxor.vv %v10 %v10 %v12;
65
    vror.vi %v10 %v10 ROTATE_FOURTH;
66
    vrgather.vv %v16 %v10 %v2;
67
    vrgather.vv %v18 %v12 %v4;
68
    vrgather.vv %v20 %v14 %v6;
69
    vle32.v %v24 (%a2);
70
    addi %a2 %a2 16;
71
    vluxei32.v %v26 (%a1) %v24;
72
    vadd.vv %v8 %v8 %v16;
73
    vadd.vv %v8 %v8 %v26;
74
    vxor.vv %v20 %v20 %v8;
75
    vror.vi %v20 %v20 ROTATE_FIRST;
76
    vadd.vv %v18 %v18 %v20;
77
    vxor.vv %v16 %v16 %v18;
78
    vror.vi %v16 %v16 ROTATE_SECOND;
79
    vle32.v %v24 (%a2);
80
    addi %a2 %a2 16;
81
    vluxei32.v %v26 (%a1) %v24;
82
    vadd.vv %v8 %v8 %v16;
83
    vadd.vv %v8 %v8 %v26;
84
    vxor.vv %v20 %v20 %v8;
85
    vror.vi %v20 %v20 ROTATE_THIRD;
86
    vadd.vv %v18 %v18 %v20;
87
    vxor.vv %v16 %v16 %v18;
88
    vror.vi %v16 %v16 ROTATE_FOURTH;
89
    // Restore row order before the next column phase.
90
    vrgather.vv %v10 %v16 %v6;
91
    vrgather.vv %v12 %v18 %v4;
92
    vrgather.vv %v14 %v20 %v2;
93
    addi %t1 %t1 -1;
94
    bnez %t1 @round;
95
    vxor.vv %v8 %v8 %v12;
96
    vxor.vv %v10 %v10 %v14;
97
    vse32.v %v8 (%a0);
98
    addi %t0 %a0 16;
99
    vse32.v %v10 (%t0);
100
    ret;